乐正

Actions speak louder than words.

Sicp-ex2-56

问题

请说明如何扩充基本求导规则,以便能够处理更多类型的表达式。例如,通过给程序deriv 添加一个新字句,并以适当方式定义过程exponentiation?baseexponentmake-exponentiation 的方式,实现下述求导规则(你可以考虑用符号**表示乘幂):

$$ \frac {d(u^n)} {dx} = nu^{n-1}(\frac {du} {dx}) $$

请将如下规则也构造到程序里:任何东西的0次幂都是1,而它们的1次幂都是其自身。

解答

练习2.56 (ex2-56.scm) download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
;; 求一个表达式的导数形式
(define (deriv exp var)
  (cond ((number? exp) 0)
        ((variable? exp)
         (if (same-variable? exp var) 1 0))
        ((sum? exp)
         (make-sum (deriv (addend exp) var)
                   (deriv (augend exp) var)))
        ((product? exp)
         (make-sum
           (make-product (multiplier exp)
                         (deriv (multiplicand exp) var))
           (make-product (deriv (multiplier exp) var)
                         (multiplicand exp))))
        ((exponentiation? exp)
         (make-product
           (make-product (exponent exp)
                         (make-exponentiation (base exp) (- (exponent exp) 1)))
           (deriv (base exp) var)))
        (else
          (error "unknown expression type -- DERIV" exp))))

(define (variable? x) (symbol? x))

(define (same-variable? v1 v2)
  (and (variable? v1) (variable? v2) (eq? v1 v2)))

(define (make-sum a1 a2)
  (cond ((=number? a1 0) a2)
        ((=number? a2 0) a1)
        ((and (number? a1) (number? a2)) (+ a1 a2))
        (else (list '+ a1 a2))))

(define (=number? exp num)
  (and (number? exp) (= exp num)))

(define (make-product m1 m2)
  (cond ((or (=number? m1 0) (=number? m2 0)) 0)
        ((=number? m1 1) m2)
        ((=number? m2 1) m1)
        ((and (number? m1) (number? m2)) (* m1 m2))
        (else (list '* m1 m2))))

(define (sum? x)
  (and (pair? x) (eq? (car x) '+)))

(define (addend s) (cadr s))

(define (augend s) (caddr s))

(define (product? x)
  (and (pair? x) (eq? (car x) '*)))

(define (multiplier p) (cadr p))

(define (multiplicand p) (caddr p))

(define (exponentiation? x)
  (and (pair? x) (eq? (car x) '**)))

(define (base exp) (cadr exp))

(define (exponent exp) (caddr exp))

(define (make-exponentiation b e)
  (cond ((=number? e 0) 1)
        ((=number? e 1) b)
        (else (list '** b e))))

测试

1
2
3
4
5
6
7
8
(deriv '(** x 3) 'x)
;Value 14: (* 3 (** x 2))

(deriv '(+ (** x 2) (* 2 x y) 3) 'x)
;Value 16: (+ (* 2 x) 2)

(deriv '(** (+ (+ x 3) (* x y)) 5) 'x)
;Value 17: (* (* 5 (** (+ (+ x 3) (* x y)) 4)) (+ 1 y))

draft

« sicp-ex2-55 sicp-ex2-57 »

Comments